10 REM ***** A EXAMPLE OF RASTER GRAPHICS ***** - Page 117

CHAPTER 2 PCL - 97 

Raster graphics example 

10 REM ***** A EXAMPLE OF RASTER GRAPHICS *****  
20 ESC$=CHR$(27)  
30 WIDTH "LPT1:",255  
40 REM --- SET GRAPHICS RESOLUTION TO 300 DPI ---  
50 LPRINT ESC$+"*t300R";  
60 REM --- START RASTER GRAPHICS ---  
70 LPRINT ESC$+"*r1A";  
80 REM --- TRANSFER RASTER GRAPHICS ---  
90 FOR I=1 TO 28  
100 REM --- TRANSFER 1 LINE OF DOTS (4 byte = line) ---  
110 LPRINT ESC$+"*b4W";  
120 FOR J=1 TO 4  
130 READ A$  
140 LPRINT CHR$(VAL("&H"+A$));  
150 NEXT J  
160 NEXT I  
170 REM --- END RASTER GRAPHICS ---  
180 LPRINT ESC$+"*rB"  
190 LPRINT  
200 LPRINT  
210 REM --- CHANGE GRAPHIC RESOLUTION  
220 LPRINT ESC$+"*t75R";  
230 REM --- START RASTER GRAPHICS ---  
240 LPRINT ESC$+"*r1A";  
250 REM --- TRANSFER RASTER GRAPHICS ---  
260 RESTORE 410  
270 FOR I=1 TO 28  
280 REM --- TRANSFER 1 LINE OF DOTS (4 byte = line) ---  
290 LPRINT ESC$+"*b4W";  
300 FOR J=1 TO 4  
310 READ A$  
320 LPRINT CHR$(VAL("&H"+A$));  
330 NEXT J  
340 NEXT I  
350 REM --- END RASTER GRAPHICS ---  
360 LPRINT ESC$+"*rB"  
370 REM --- PAPER EJECT ---  
380 LPRINT CHR$(12);  
390 END  
400 REM --- RASTER DATA ---  
410 DATA 00,1F,E0,00  
420 DATA 00,7F,F8,00  
430 DATA 01,F0,3E,00  
440 DATA 03,C0,0F,00  
450 DATA 07,00,03,80  
460 DATA 0E,00,01,C0  
470 DATA 1C,38,70,E0  
480 DATA 18,70,70,60  
490 DATA 38,38,70,70  
500 DATA 30,00,00,30  
510 DATA 70,00,00,38  
520 DATA 61,00,02,18  
530 DATA 61,00,02,18  
540 DATA 6F,80,07,98  
550 DATA 67,80,07,D8  
560 DATA 61,80,06,18  
570 DATA 61,C0,0E,18  
580 DATA 70,E0,1C,38  
590 DATA 30,70,78,30  
600 DATA 38,3F,F0,70  
610 DATA 18,0F,C0,60  
620 DATA 1C,00,00,E0  
630 DATA 0E,00,01,C0  
640 DATA 07,00,03,80  
650 DATA 03,C0,0F,00  
660 DATA 01,F0,3E,00  
670 DATA 00,7F,F8,00  
680 DATA 00,1F,E0,00  
690 REM --- DATA END --- 
 
<Sample file 8>